Door open signal on old cars

marcocamilleri1111

This I was thinking 🤔

Mikescotland

marcocamilleri1111 yes, that would work, just program either esp32 or arduino to canbox uart protocol. Search for my post regarding clio III canbus (ignore canbus translation part and connect switches via GPIOs.). If you plan to use 12V for switching, remember to make voltage divider either for 3.3V (esp) or 5V (arduino), although personally I'd rather use switching to ground, this simplifies things.
However, for icons to have on the screen when door is open, it seems to be pointless from work involved perspective with installing wires and switches etc.

marcocamilleri1111

Hi,Mikescotland thanks for your help👍🏻
for me to install 5 wires GND from the door switches Not a problem but programing I don't know 😕

Mikescotland

marcocamilleri1111 if you wait a few days I'll give you detailed schematic, code and what to do instructions.
What country you're from? And what car you're "converting"?

marcocamilleri1111

I am from Malta ,and I have a Nissan patrol Gu 2001 zd30, and if possible head lights on because I want to fit dudu ambient lighting,
Thanks Mike your the best 👍🏻

Mikescotland

marcocamilleri1111 cool. So I'll prepare for you doors and headlights. Bear in mind hood is not available, so it will be 4 doors and the boot.
I'm in the UK so probably I could even send you programmed ESP32 for this project.

marcocamilleri1111

Thanks 👍🏻👍🏻👍🏻👍🏻👍🏻

marcocamilleri1111

Hey Mike thanks again for your help , how's it going ?

Mikescotland

marcocamilleri1111 Lost your post in this forum.
I attach schematics and here is arduino code for ESP32c3 supermini (it's very small board to be powered from dudu USB port). Canbox version Raise Toyota ALL

#include <HardwareSerial.h>

// =========================================================================
// Configuration
// =========================================================================

// GPIO Pin Definitions
#define FRONT_RIGHT_DOOR_PIN 2 // UK Driver's Door
#define FRONT_LEFT_DOOR_PIN  3 // UK Passenger's Door
#define REAR_LEFT_DOOR_PIN   1
#define REAR_RIGHT_DOOR_PIN  0
#define BOOT_PIN             4
#define HEADLIGHTS_PIN       5
#define LEFT_INDICATOR_PIN   6
#define RIGHT_INDICATOR_PIN  7

// UART to headunit
const int  UART_TX_PIN    = 20;
const long UART_BAUD_RATE = 38400;
HardwareSerial UartPort(1);

// Timeout for stabilizing blinking indicator signals (in milliseconds)
const unsigned long INDICATOR_TIMEOUT = 1200;

// Global state variables
uint8_t currentDoorStateMask = 0;
uint8_t currentLightStateMask = 0;
unsigned long lastLeftIndicatorTime = 0;
unsigned long lastRightIndicatorTime = 0;

// Timers for periodic sends
unsigned long lastDoorSendTime = 0;
unsigned long lastLightSendTime = 0;

// --- New ---
// Flag to ensure initial status is sent only once after boot
bool initialStatusSent = false;


// =========================================================================
// Headunit Communication Functions (Based on RAISE RAV4 Protocol)
// =========================================================================

/**
 * @brief Sends the Door Status frame to the headunit.
 * Implements the protocol for CMD_DOOR_STATUS (0x24).
 * Frame: 2E 24 01 [Mask] [Checksum]
 * @param mask The bitmask representing the state of all open doors.
 */
void sendDoorCommand(uint8_t mask) {
  const uint8_t HEADER = 0x2E;
  const uint8_t COMMAND = 0x24;
  const uint8_t LENGTH = 0x01;

  uint8_t checksum = (COMMAND + LENGTH + mask) ^ 0xFF;

  uint8_t frame[5] = {HEADER, COMMAND, LENGTH, mask, checksum};
  UartPort.write(frame, 5);
}

/**
 * @brief Sends the Light Status frame to the headunit.
 * Implements the protocol for CMD_MULTI_FUNCTION (0x7D) with sub-command 0x01.
 * Frame: 2E 7D 02 01 [Mask] [Checksum]
 * @param mask The bitmask representing the state of the lights.
 */
void sendLightCommand(uint8_t mask) {
  const uint8_t HEADER = 0x2E;
  const uint8_t COMMAND = 0x7D;
  const uint8_t LENGTH = 0x02;
  const uint8_t SUB_COMMAND = 0x01;

  uint8_t checksum = (COMMAND + LENGTH + SUB_COMMAND + mask) ^ 0xFF;

  uint8_t frame[6] = {HEADER, COMMAND, LENGTH, SUB_COMMAND, mask, checksum};
  UartPort.write(frame, 6);
}


// =========================================================================
// Main Sketch
// =========================================================================

void setup() {
  // USB-Serial for debugging
  Serial.begin(115200);
  Serial.println("RAV4 Protocol Emulator Started (Doors LOW when closed).");

  // Headunit UART port
  UartPort.begin(UART_BAUD_RATE, SERIAL_8N1, -1, UART_TX_PIN);

  // Configure Door & Boot pins as INPUT_PULLUP
  pinMode(FRONT_RIGHT_DOOR_PIN, INPUT_PULLUP);
  pinMode(FRONT_LEFT_DOOR_PIN, INPUT_PULLUP);
  pinMode(REAR_LEFT_DOOR_PIN, INPUT_PULLUP);
  pinMode(REAR_RIGHT_DOOR_PIN, INPUT_PULLUP);
  pinMode(BOOT_PIN, INPUT_PULLUP);

  // Configure Light pins as standard INPUT
  pinMode(HEADLIGHTS_PIN, INPUT);
  pinMode(LEFT_INDICATOR_PIN, INPUT);
  pinMode(RIGHT_INDICATOR_PIN, INPUT);
}

void loop() {
  unsigned long now = millis();

  // ─────────────────────────────────────────────────────────────────────────
  // 1) Read GPIOs and build protocol-specific state masks
  // ─────────────────────────────────────────────────────────────────────────

  // -- Build Door Mask --
  uint8_t newDoorMask = 0;
  if (digitalRead(FRONT_RIGHT_DOOR_PIN) == HIGH) newDoorMask |= 0x80;
  if (digitalRead(FRONT_LEFT_DOOR_PIN) == HIGH)  newDoorMask |= 0x40;
  if (digitalRead(REAR_LEFT_DOOR_PIN) == HIGH)   newDoorMask |= 0x10;
  if (digitalRead(REAR_RIGHT_DOOR_PIN) == HIGH)  newDoorMask |= 0x20;
  if (digitalRead(BOOT_PIN) == HIGH)             newDoorMask |= 0x08;

  // -- Build Light Mask --
  uint8_t newLightMask = 0;
  if (digitalRead(HEADLIGHTS_PIN) == HIGH) newLightMask |= 0x40;

  // Logic for Blinking Indicators
  if (digitalRead(LEFT_INDICATOR_PIN) == HIGH) lastLeftIndicatorTime = now;
  if (digitalRead(RIGHT_INDICATOR_PIN) == HIGH) lastRightIndicatorTime = now;
  if (now - lastLeftIndicatorTime < INDICATOR_TIMEOUT) newLightMask |= 0x10;
  if (now - lastRightIndicatorTime < INDICATOR_TIMEOUT) newLightMask |= 0x08;


  // ─────────────────────────────────────────────────────────────────────────
  // 2) One-time status send 3 seconds after boot
  // ─────────────────────────────────────────────────────────────────────────
  if (!initialStatusSent && now >= 3000) {
    sendDoorCommand(newDoorMask);
    sendLightCommand(newLightMask);

    // Synchronize current state to prevent immediate re-transmission
    currentDoorStateMask = newDoorMask;
    currentLightStateMask = newLightMask;
    
    initialStatusSent = true; // Set flag to prevent this from running again
    Serial.println("Initial 3-second status sent.");
  }


  // ─────────────────────────────────────────────────────────────────────────
  // 3) Scheduled sends to headunit (only on state change)
  // ─────────────────────────────────────────────────────────────────────────
  if (now - lastDoorSendTime >= 250) {
    if (newDoorMask != currentDoorStateMask) {
      currentDoorStateMask = newDoorMask;
      sendDoorCommand(currentDoorStateMask);
      lastDoorSendTime = now;
    }
  }

  if (now - lastLightSendTime >= 200) {
    if (newLightMask != currentLightStateMask) {
      currentLightStateMask = newLightMask;
      sendLightCommand(currentLightStateMask);
      lastLightSendTime = now;
    }
  }

  delay(20);
}

marcocamilleri1111

Mikescotland
You are amazing 🤩 , thank you for your outstanding work on this project ,your dadication and skill are clearly visible 👍🏻👍🏻. Next step I give it a try i will try to program one of those ESP and see how it goes 😜

marcocamilleri1111

Mikescotland
Hi Mike that worked perfectly I just received it today and I did it ,by any chance is it possible to change the status of the doors from settings because if I take GND for door switch is on when the door is open thanks 👍🏻

surfer63

DUDU-Meng OBD and CAN are different protocols.

Not correct.
The CAN bus is one of five protocols used in the on-board diagnostics (OBD)-II vehicle diagnostics standard. The OBD-II standard has been mandatory for all cars sold in the United States since model year 1996.
The EOBD standard has been mandatory for all petrol cars/trucks sold in the European Union since 2001 and all diesel cars/trucks since 2004.
Can bus is (a very specific) part of OBD-II. The protocols "simply" need to be accessed in different ways.
In know that VAG (Volkswagen/Skoda/Seat/Audi) use "section 17" for all CANbus related data inside OBD, next to the standard basic CANbus data.

DUDU-Meng Most OBD systems do not provide the data you mentioned.

Correct. OBD was designed and now mandatory to comply with emission standards and detect failures in the emission or exceeding the emission levels (remember the Volkswagen diesel scandal?). So, most standard OBD extensions do not support open doors, lights, airco, etcetera. These are in the CANbus section.

JhonnyD On Suzukis until 2024 ALL informations are provided via OBD. There is no Canbus.

Yes and No. All information is provided via OBD, but Suzukis do have CANbusses. But they are only used internally inside the car for communication and engine/car control. It does not expose any data to the driver via CAN, only via OBD. You do not need a CANbus decoder in your Suszuki.

Mikescotland

surfer63 I had similar discussion with him in another topic. Didn't go anywhere... 😂

Mikescotland

marcocamilleri1111 if you have any troubles let me know, I'll assemble on a uni board and send it to you.

abidali

Mikescotland is this possible in Corolla base variant 11th gen? Using OBD? Canbus not supported.

marcocamilleri1111

Mikescotland Great thanks 👍🏻

Mikescotland

abidali unlikely, I'm yet to know any car that sends door info over obd.
Canbus, as far as I know, your car should send door info. If that doesn't show, canbox doesn't support it, so either try with another canbox (raise is probably the best choice) and fiddle with different cars in the canbus mode, or, canbus sniffing and develop own canbus decoder.
If you want to use the above schematics for door / lights, if you have existing canbus, you would need to alter the schematics and code to aceept RX/TX from existing canbox, inject frames with doors, and output to Dudu RX/TX.

Mikescotland

marcocamilleri1111 so when the door is open Dudu shows closed and the opposite?

marcocamilleri1111

Mikescotland Hi Mike,when a door opens, the switch closes, connecting the circuit to ground (earth).

marcocamilleri1111

Mikescotland

marcocamilleri1111 Just logic needs to be changed in the sketch:

// HIGH meant closed before; set bits on HIGH
if (digitalRead(FRONT_RIGHT_DOOR_PIN) == HIGH) newDoorMask |= 0x80;
if (digitalRead(FRONT_LEFT_DOOR_PIN) == HIGH) newDoorMask |= 0x40;
if (digitalRead(REAR_LEFT_DOOR_PIN) == HIGH) newDoorMask |= 0x10;
if (digitalRead(REAR_RIGHT_DOOR_PIN) == HIGH) newDoorMask |= 0x20;
if (digitalRead(BOOT_PIN) == HIGH) newDoorMask |= 0x08;
// LOW (GND) means DOOR OPEN now; set bits on LOW
if (digitalRead(FRONT_RIGHT_DOOR_PIN) == LOW) newDoorMask |= 0x80;
if (digitalRead(FRONT_LEFT_DOOR_PIN) == LOW) newDoorMask |= 0x40;
if (digitalRead(REAR_LEFT_DOOR_PIN) == LOW) newDoorMask |= 0x10;
if (digitalRead(REAR_RIGHT_DOOR_PIN) == LOW) newDoorMask |= 0x20;
if (digitalRead(BOOT_PIN) == LOW) newDoorMask |= 0x08;

Here's full sketch (provided you have resistors as per schematic):

#include <HardwareSerial.h>

// =========================================================================
// Configuration
// =========================================================================

// GPIO Pin Definitions
#define FRONT_RIGHT_DOOR_PIN 2 // UK Driver's Door
#define FRONT_LEFT_DOOR_PIN  3 // UK Passenger's Door
#define REAR_LEFT_DOOR_PIN   1
#define REAR_RIGHT_DOOR_PIN  0
#define BOOT_PIN             4
#define HEADLIGHTS_PIN       5
#define LEFT_INDICATOR_PIN   6
#define RIGHT_INDICATOR_PIN  7

// UART to headunit
const int  UART_TX_PIN    = 20;
const long UART_BAUD_RATE = 38400;
HardwareSerial UartPort(1);

// Timeout for stabilizing blinking indicator signals (in milliseconds)
const unsigned long INDICATOR_TIMEOUT = 1200;

// Global state variables
uint8_t currentDoorStateMask = 0;
uint8_t currentLightStateMask = 0;
unsigned long lastLeftIndicatorTime = 0;
unsigned long lastRightIndicatorTime = 0;

// Timers for periodic sends
unsigned long lastDoorSendTime = 0;
unsigned long lastLightSendTime = 0;

// Flag to ensure initial status is sent only once after boot
bool initialStatusSent = false;


// =========================================================================
// Headunit Communication Functions (Based on RAISE RAV4 Protocol)
// =========================================================================

/**
 * @brief Sends the Door Status frame to the headunit.
 * Implements the protocol for CMD_DOOR_STATUS (0x24).
 * Frame: 2E 24 01 [Mask] [Checksum]
 * @param mask The bitmask representing the state of all open doors.
 */
void sendDoorCommand(uint8_t mask) {
  const uint8_t HEADER = 0x2E;
  const uint8_t COMMAND = 0x24;
  const uint8_t LENGTH = 0x01;

  uint8_t checksum = (COMMAND + LENGTH + mask) ^ 0xFF;

  uint8_t frame[5] = {HEADER, COMMAND, LENGTH, mask, checksum};
  UartPort.write(frame, 5);
}

/**
 * @brief Sends the Light Status frame to the headunit.
 * Implements the protocol for CMD_MULTI_FUNCTION (0x7D) with sub-command 0x01.
 * Frame: 2E 7D 02 01 [Mask] [Checksum]
 * @param mask The bitmask representing the state of the lights.
 */
void sendLightCommand(uint8_t mask) {
  const uint8_t HEADER = 0x2E;
  const uint8_t COMMAND = 0x7D;
  const uint8_t LENGTH = 0x02;
  const uint8_t SUB_COMMAND = 0x01;

  uint8_t checksum = (COMMAND + LENGTH + SUB_COMMAND + mask) ^ 0xFF;

  uint8_t frame[6] = {HEADER, COMMAND, LENGTH, SUB_COMMAND, mask, checksum};
  UartPort.write(frame, 6);
}


// =========================================================================
// Main Sketch
// =========================================================================

void setup() {
  // USB-Serial for debugging
  Serial.begin(115200);
  Serial.println("RAV4 Protocol Emulator Started (Doors: LOW=OPEN, HIGH=CLOSED).");

  // Headunit UART port
  UartPort.begin(UART_BAUD_RATE, SERIAL_8N1, -1, UART_TX_PIN);

  // -------- CHANGED: use external pull-ups, so plain INPUT ----------
  pinMode(FRONT_RIGHT_DOOR_PIN, INPUT);
  pinMode(FRONT_LEFT_DOOR_PIN,  INPUT);
  pinMode(REAR_LEFT_DOOR_PIN,   INPUT);
  pinMode(REAR_RIGHT_DOOR_PIN,  INPUT);
  pinMode(BOOT_PIN,             INPUT);
  // ------------------------------------------------------------------

  // Configure Light pins as standard INPUT
  pinMode(HEADLIGHTS_PIN, INPUT);
  pinMode(LEFT_INDICATOR_PIN, INPUT);
  pinMode(RIGHT_INDICATOR_PIN, INPUT);
}

void loop() {
  unsigned long now = millis();

  // ─────────────────────────────────────────────────────────────────────────
  // 1) Read GPIOs and build protocol-specific state masks
  // ─────────────────────────────────────────────────────────────────────────

  // -- Build Door Mask --
  // CHANGED: LOW (GND) means DOOR OPEN -> set bit on LOW
  uint8_t newDoorMask = 0;
  if (digitalRead(FRONT_RIGHT_DOOR_PIN) == LOW) newDoorMask |= 0x80;
  if (digitalRead(FRONT_LEFT_DOOR_PIN)  == LOW) newDoorMask |= 0x40;
  if (digitalRead(REAR_LEFT_DOOR_PIN)   == LOW) newDoorMask |= 0x10;
  if (digitalRead(REAR_RIGHT_DOOR_PIN)  == LOW) newDoorMask |= 0x20;
  if (digitalRead(BOOT_PIN)             == LOW) newDoorMask |= 0x08;

  // -- Build Light Mask -- (unchanged)
  uint8_t newLightMask = 0;
  if (digitalRead(HEADLIGHTS_PIN) == HIGH) newLightMask |= 0x40;

  // Logic for Blinking Indicators (unchanged)
  if (digitalRead(LEFT_INDICATOR_PIN) == HIGH)  lastLeftIndicatorTime  = now;
  if (digitalRead(RIGHT_INDICATOR_PIN) == HIGH) lastRightIndicatorTime = now;
  if (now - lastLeftIndicatorTime  < INDICATOR_TIMEOUT) newLightMask |= 0x10;
  if (now - lastRightIndicatorTime < INDICATOR_TIMEOUT) newLightMask |= 0x08;

  // ─────────────────────────────────────────────────────────────────────────
  // 2) One-time status send 3 seconds after boot
  // ─────────────────────────────────────────────────────────────────────────
  if (!initialStatusSent && now >= 3000) {
    sendDoorCommand(newDoorMask);
    sendLightCommand(newLightMask);

    currentDoorStateMask  = newDoorMask;
    currentLightStateMask = newLightMask;

    initialStatusSent = true;
    Serial.println("Initial 3-second status sent.");
  }

  // ─────────────────────────────────────────────────────────────────────────
  // 3) Scheduled sends to headunit (only on state change)
  // ─────────────────────────────────────────────────────────────────────────
  if (now - lastDoorSendTime >= 250) {
    if (newDoorMask != currentDoorStateMask) {
      currentDoorStateMask = newDoorMask;
      sendDoorCommand(currentDoorStateMask);
      lastDoorSendTime = now;
    }
  }

  if (now - lastLightSendTime >= 200) {
    if (newLightMask != currentLightStateMask) {
      currentLightStateMask = newLightMask;
      sendLightCommand(currentLightStateMask);
      lastLightSendTime = now;
    }
  }

  delay(20);
}

« Previous Page